Sub setLabels()
On Error GoTo err_setLabels
'散布図にデータラベルをセットするマクロ
'X軸のデータ数とラベルの数は等しいこと
'Y軸のデータ系列は１つのみ　2010/08/28 pPoy
    Dim stRngX As String                'X軸のデータ範囲
    Dim mySRS As Object                 'グラフのデータ系列
    Dim rngL As Range                   'ラベルのデータ範囲
    Dim cntX As Long, cntL As Long
    Dim stMES As String
    Dim i As Long
    
    'X軸のデータ範囲文字列取得
    If ActiveChart Is Nothing Then
        MsgBox "グラフを１つ選択してください！", vbOKOnly
        Exit Sub
    Else
        Set mySRS = ActiveChart.SeriesCollection(1)
        stRngX = Split(mySRS.Formula, ",")(1)
        cntX = Range(stRngX).Cells.Count
    End If
    
    'ラベルのデータ範囲取得
    stMES = "ラベルのデータ範囲を選択してください。(見出し行は除外)"
    Set rngL = Application.InputBox(Prompt:=stMES, Type:=8)
    cntL = rngL.Cells.Count
    
    'チェック
    If cntX <> cntL Then
        stMES = "X軸のデータ数とラベルのデータ数が違います！"
        stMES = stMES & vbNewLine
        stMES = stMES & "最初からやり直してください。"
        MsgBox stMES, vbOKOnly
        Exit Sub
    End If
    
    'ラベルセット処理開始
    For i = 1 To cntX
        With mySRS.Points(i)
            'データが無い場合はスキップ
            On Error Resume Next
            .HasDataLabel = True
            .DataLabel.Text = rngL.Cells(i).Value
        End With
    Next i
    MsgBox "処理終了〜", vbOKOnly
    
exit_setLabels:
    Exit Sub
    
err_setLabels:
    Select Case Err.Number
        Case 424
            'InputBoxでキャンセルされた場合
            MsgBox "最初からやり直してください", vbOKOnly
            Err.Clear
        Case Else
            'その他のエラー
            MsgBox Err.Number & " - " & Err.Description
    End Select
    Resume exit_setLabels
End Sub

• ここで実行した結果は、元に戻せません。
  シート若しくは Book のコピーを取った後、コピーしたグラフでこのマクロを試してください。
  
  
• このマクロは、XY グラフをひとつ選択してから実行してください。
  シート上に複数のグラフが存在する場合、選択されているグラフに対してのみ マクロが実行されます。
  グラフが選択されてない場合は処理が中止されます。
  
  
• このマクロでは、Y軸の系列は１つのみの前提です。 複数の系列がある場合は、コードの修正が必要です。
  
  
• このマクロでは、X軸のデータ範囲の数と、データラベルの範囲の数が等しいことが前提です。
  数が異なっている場合は、処理が中止されます。
  
  
• データラベルの範囲を取得するために、「InputBox メソッド」 を使用しています。
  これは、「InputBox 関数」 とは異なり、セル範囲を取得することができます。
  
  
• 一応エラー処理セクションを作ってありますが、それ以外のエラーがありそうな場合は追加してください。