Sub CreatGraphData()
On Error GoTo Err_CreatGraphData
'リンク切れのグラフから、データを新規シートに書き出し後、
'グラフデータとして再設定するマクロ 2010/02/21 pPoy
'予め対象となるグラフを選択しておくこと
    Dim myGraph As Object                   'ActiveChart
    Dim cntRows As Integer                  '系列内データ数
    Dim X As Object                         'グラフ系列
    Dim i As Integer
    i = 2
    
    'グラフ取得
    If ActiveChart Is Nothing Then
        MsgBox "グラフを１つ選択してください！", vbOKOnly
        Exit Sub
    End If
    Set myGraph = ActiveChart
    '最初のデータ系列の値の個数
    cntRows = UBound(myGraph.SeriesCollection(1).Values)
    
    '新規シート追加
    Worksheets.Add
    With ActiveSheet
        .Cells(1, 1) = "Ｘ軸"
    
        'A列にX軸の値を抽出後書き出し(配列内の値を縦横変換後)
        .Range(.Cells(2, 1), .Cells(cntRows + 1, 1)) = _
        Application.Transpose(myGraph.SeriesCollection(1).XValues)
    
        For Each X In myGraph.SeriesCollection
            'B列から順番に書き出す
            '系列名
            .Cells(1, i) = X.Name
            '系列内の値
            .Range(.Cells(2, i), .Cells(cntRows + 1, i)) = _
            Application.Transpose(X.Values)
            i = i + 1
        Next X
        
        '☆書き出したデータをグラフデータとして再設定
　　　　'手動で再設定する場合は、この下をコメントアウトしてください
        myGraph.SetSourceData _
            Source:=.Range("A1").CurrentRegion, PlotBy:=xlColumns
　　　　'手動で再設定する場合は、この上までコメントアウトしてください
    End With
    
Exit_CreatGraphData:
    Set myGraph = Nothing
    Exit Sub

Err_CreatGraphData:
    MsgBox Err.Description, vbExclamation + vbOKOnly
    Resume Exit_CreatGraphData
End Sub

• このマクロ実行する前に、予めグラフを１つだけ選択しておくことが必要です。
  複数のグラフを選択した状態では このマクロは動きません。
  
  
• ワークシート上に貼り付けたグラフだけでなく、グラフシートのグラフからもデータを取り出せます。
  
  
• マクロを実行するたびに、新規シートが一枚追加され、グラフデータのリンク先が新しいシートに変更されます。
  
  
• 複雑なグラフでは、リンクの再設定で失敗する可能性があります。
  例えば、グラフ系列を飛び飛びに設定してある場合では、全ての系列が正しく設定できません。
  
  その場合は、リンクの再設定の箇所 (「☆書き出したデータをグラフデータとして再設定」 の下の行) を
  コメントアウトして実行し、リンク再設定は値を確認しながら手動で行ってください。
  
  
• このマクロでリンクの再設定を行ったグラフは元に戻せません。
  必ずバックアップを取ってからテストしてください。