Sub excel_Quit1()
'自分自身を保存しないで閉じる 2006/10/08 pPoy
'同時に Excel も終了する
'ただし自分以外の Book は保存の問い合わせが出る

    '保存したことにする (保存はしない)
    ThisWorkbook.Saved = True
    'Excel を終了する
    Application.Quit
    'Book を閉じる
    ThisWorkbook.Close False
End Sub

Sub excel_Quit2()
'自分自身のみ保存しないで閉じる　2006/10/08 pPoy
'他の Book に対しては何もしない
'他に開いている Book が無い場合のみ Excel も終了する
    With ThisWorkbook
        If Workbooks.Count > 1 Then
            '他の Book あり
                '保存したことにする (保存はしない)
                .Saved = True
                '自Book を閉じる
                .Close False
        Else
            '単独で Open 時
                '保存したことにする (保存はしない)
                .Saved = True
                'Excel を終了する
                Application.Quit
                'Book を閉じる
                .Close
        End If
    End With
End Sub

Sub excel_Quit3()
'自分自身は保存しないで閉じる　2006/10/08 pPoy
'他の Book は保存して閉じる
'最後に Excel も終了する
    Dim w As Workbook
    'まず、自分以外の Book を保存して閉じる
    For Each w In Workbooks
        If w.Name <> ThisWorkbook.Name Then
            w.Close SaveChanges:=True
        End If
    Next
    
    '自分自身は保存したことにする (保存はしない)
    ThisWorkbook.Saved = True
    'Excel を終了する
    Application.Quit
    'Book を閉じる
    ThisWorkbook.Close False
End Sub

Sub excel_Quit4()
'全ての Book を保存しないで閉じる　2006/10/08 pPoy
'最後に Excel も終了する
    Dim w As Workbook
    '全ての Book を保存したことにする (保存はしない)
    For Each w In Workbooks
        w.Saved = True
    Next
    
    'Excel を終了する
    Application.Quit
    'Book を閉じる
    ThisWorkbook.Close False
End Sub

Sub excel_Quit5()
'全ての Book を保存して閉じる　2006/10/08 pPoy
'最後に Excel も終了する
    Dim w As Workbook
    '全ての Book を保存する
    For Each w In Workbooks
        w.Save
    Next
    
    'Excel を終了する
    Application.Quit
    'Book を閉じる
    ThisWorkbook.Close False
End Sub

• 正確なインスタンスの解説は、インスタンス　【instance】 を参照してください。
  （IT用語辞典 e-Words による用語の説明です）
  ここで使用している 「Excel のインスタンス」 とは、開いている Excel Application
  のことを指しています。
  
  
• Windows の 「スタート」−「プログラム」−「Microsoft Excel」 から開いた Excel は、
  既に Excel が開かれている場合でも、「新しいインスタンス」 で開かれます。
  
  
• 既に Excel が開かれている場合、ファイル名をダブルクリックして開いた Book は、
  先に開かれた Excel の 「既存のインスタンス」 を使用して開かれます。
  
  
• Excel 2002 の場合、同じインスタンスで開いた Book は、1つの Excel 画面の後ろに
  隠れてしまいます。
  別のインスタンスで開いた Book は、別々の Excel 窓に表示されます。

• 上の、1. 〜 4. の方法は、コード実行中の Book を 保存しないで イキナリ閉じます。
  コードのテストをする前に、予め保存しておくことをお勧めします。(^^ゞ
  
  
• 上の 「他の Book 」 や、「全ての Book 」 とは、同じインスタンスで開いた Book が対象です。
  別のインスタンスで開かれている Book には影響しません。
  
  
• Excel VBA で自分自身を閉じるためには、コードの順番が大切です。
  先に、Quit してから Close をすると綺麗に閉じることができます。
  ※ ちょっと逆のような気がしますが。。。(^^ゞ