• 　新規テーブル名を、［分類別リスト］とします。　フィールドは２つ作成します。
  
• 　最初に、［分類］フィールドをテキスト型で作ります。
  　これに［主キー］を設定してください。 　サイズは分類名の収まる長さとします。
• 　次に、［頁番号］フィールドを、長整数型でつくります。 　

　　Option Compare Database
　　Option Explicit

　　' DAOを使ってグループ毎にページ番号を振る
　　' 2002/07/13 pPoy

　　Dim DB As dao.Database
　　Dim GrPages As dao.Recordset

　　Function GetGrPages()
　　　　' 頁番号表示用関数
    　　GrPages.Seek "=", Me![分類]
    　　If Not GrPages.NoMatch Then
        　　GetGrPages = Me.Page & "/" & GrPages![頁番号]
    　　End If
　　End Function

    Private Sub Report_Open(Cancel As Integer)
    　　'予め古い頁数の情報を削除し、インデックスを設定
        Set DB = CurrentDb()
    　　DB.Execute "DELETE * FROM [分類別リスト];"
    　　Set GrPages = DB.OpenRecordset("分類別リスト", dbOpenTable)
    　　GrPages.Index = "PrimaryKey"
    End Sub

　　Private Sub グループヘッダー0_Format(Cancel As Integer, FormatCount As Integer)
　　　　'ページ番号の初期化
    　　Me.Page = 1
　　End Sub

    Private Sub ページフッター_Format(Cancel As Integer, FormatCount As Integer)
    　　'頁番号格納用テーブルに、グループ毎の頁数を入力
        GrPages.Seek "=", Me![分類]
        If Not GrPages.NoMatch Then
            If GrPages![頁番号] < Me.Page Then
                GrPages.Edit
                GrPages![頁番号] = Me.Page
                GrPages.Update
            End If
        Else
            GrPages.AddNew
            GrPages![分類] = Me![分類]
            GrPages![頁番号] = Me.Page
            GrPages.Update
        End If
          
    End Sub

• テキストボックス 1　(ここに、グループ毎の頁数を表示します)
  　コントロールソース:　=GetGrPages()
• テキストボックス 2　(コレは、非表示に設定します)
  　コントロールソース:　=Pages

　　分類　　コード　　　　品名
　　------------------------------------------
　　飲物　　　
　　　　　　　1　　　　　100%オレンジ
　　　　　　　2　　　　　100%グレープ
　　　　　　　3　　　　　100%レモン

　　　　〜〜〜〜〜〜〜〜〜〜〜

　　　　　　　11　　　　コーヒーミルク
　　　　　　　12　　　　美味しいお茶
　　------------------------------------------
　　１/３


のように表示されます。

• DAO を使用しますので、Access2000 及び AccessXP の場合は、
  DAO への参照設定　が必要です。
  
  
• 予めレポートには ［分類］ で、グループ化を設定し、 「グループヘッダー」 と
  「グループフッター」 を表示してください。
  
  
• これはページフッター以外では正しく動きません。
  
  
• これは、以下のマイクロソフト技術情報を元に作成したものです。
  (より解り易く加工したつもりですが、それでも不明な点は本家？の方をどうぞ。)
  
  [AC97]レポートでグループ毎にPage/Pages形式のページ番号をつける方法
  
  
• ADO 利用の場合は、こちら