Public Function AllProcName(ByVal strModuleName As String) As String
'標準モジュール内のプロシージャ名一覧を取得。　2005/03/12 pPoy
On Error GoTo procErr
    Dim mdl As Module                   'Moduleオブジェクト
    Dim lngDecCnt As Long               '宣言セクションの行数
    Dim strName As String               'プロシージャ名比較用
    Dim strProcName As String           '全プロシージャ名
    Dim lngR As Long                    'プロシージャの種類
    Dim i As Long                       'カウンタ

    'Moduleオブジェクト取得
    DoCmd.OpenModule strModuleName
    Application.VBE.MainWindow.Visible = False
    Set mdl = Modules(strModuleName)
    
    '宣言セクションの行数格納
    lngDecCnt = mdl.CountOfDeclarationLines
    
    '最初のプロシージャ名格納
    strName = mdl.ProcOfLine(lngDecCnt + 1, lngR)
    strProcName = strName & vbNewLine
    
    '宣言セクションの次行から最終行までループ
    For i = lngDecCnt + 1 To mdl.CountOfLines
        '新規プロシージャ名取得
        If strName <> mdl.ProcOfLine(i, lngR) Then
            strName = mdl.ProcOfLine(i, lngR)
            'プロシージャ名追加
            strProcName = strProcName & strName & vbNewLine
        End If
    Next i
    
exit_AllProcName:
    '終了処理
    DoCmd.Close acModule, strModuleName, acSaveNo
    Set mdl = Nothing
    AllProcName = strProcName
    Exit Function
    
procErr:
    '名前が見つからない場合
    AllProcName = ""
    Resume exit_AllProcName
End Function

Private Sub cmd_ProcName_Click()
    Dim strName As String
    Const mdlName = "標準モジュール名"
    strName = AllProcName(mdlName)
    If strName <> "" Then
        MsgBox strName, vbOKOnly, "「" & mdlName & "」 内のプロシージャ名一覧"
    Else
        MsgBox "プロシージャはみつかりませんでした。", vbOKOnly
    End If
End Sub

• プロシージャ名取得の際 VBE 画面を開く必要がある為、一瞬画面が瞬きます。
  
  
• 指定したモジュールが開いていた場合、無条件に閉じてしまいます。
  コードに変更を加えた場合は、必ず保存してからこの関数を実行してください。
  
  
• 指定したモジュールが無い場合は、長さ零の文字列が返ります
  
  
• 参考用
  モジュール名一覧を DAO で取得する方法は、こちら です。
  モジュール名一覧を AccessObject で取得する方法は、こちら です。
  レポート内のプロシージャ名を取得する関数は、こちら です。
  フォーム内のプロシージャ名を取得する関数は、こちら です。