Option Compare Database      '※ この２行は最初からあります。
Option Explicit              '※ 無ければ追加してください。

'画像保存用のサーバ内フォルダパス 
'\\で始まるパスはお使いの環境に合わせて変更してください
Const imgPath = "\\ImgFileServer\Imgs"    '※ パス例

'休止用 API関数
Private Declare Sub Sleep Lib "KERNEL32.dll" _
    (ByVal dwMilliseconds As Long)

Private Sub Form_Current()
On Error GoTo Err_Form_Current
'画像をテーブルに保存せず直接ファイルから表示する処理　2008/01/03 pPoy
    Dim fPath As String                 '画像のフルパス

    If IsNull(Me!FileName) Then
        '新規レコードに移動した際はデザイン時の画像を表示
        Me!img_1.Picture = imgPath & "\くまさん.gif"
    Else
        '画像をフルパスでセット
        fPath = imgPath & "\" & Me!FileName
        Me!img_1.Picture = fPath
    End If
    
Exit_Form_Current:
    Exit Sub
    
Err_Form_Current:
    MsgBox Err.Description
    Resume Exit_Form_Current
End Sub

Private Sub FileName_AfterUpdate()
'画像ファイルセット処理コール 2008/01/03 pPoy
    Call Form_Current
End Sub

Private Sub img_1_Click()
On Error GoTo Err_img_1_Click
'画像をクリックしたら画像ファイルをIEでオープン　2008/01/03 pPoy
    Dim objIE As Object                  'InternetExplorer.application
    Dim fPath As String                  '画像のフルパス
    
    '画像が無ければ何もしない
    If IsNull(Me!FileName) Then Exit Sub
    
    '画像ファイルパスセット
    fPath = "file:\\" & imgPath & "\" & Me!FileName

    'IEをブランクでオープン
    Set objIE = CreateObject("InternetExplorer.application")
    With objIE
        'ツールバー・ステータスバー・アドレスバー非表示
        .Toolbar = 0
        .StatusBar = 0
        .AddressBar = 0
        'ブランクでオーブン
        .Navigate "about:blank"
    End With
    DoEvents        'ちょっと一息
    
    With objIE
        .Navigate fPath                 'IEに画像セット
        .Width = 350                    '※ IEの幅   
        .Height = 450                   '※ IEの高さ
        .Document.Title = Me.myMemo     'IEのタイトルセット
        .Visible = True                 'IE表示
    End With
    
    '表示終了まで待ってから IEオブジェクト開放
    Do While (objIE.Busy)
        Sleep 200                       '0.2秒休止
    Loop
    Set objIE = Nothing

Exit_img_1_Click:
    Exit Sub

Err_img_1_Click:
    MsgBox Err.Description
    Resume Exit_img_1_Click
End Sub

'マウスカーソルを変更するAPI関数
Private Declare Function LoadCursor Lib "user32" Alias "LoadCursorA" _
    (ByVal hInstance As Long, ByVal lpCursorName As Long) As Long
Private Declare Function SetCursor Lib "user32" _
    (ByVal hCursor As Long) As Long
    
Const IDC_HAND = 32649&        'ハンドカーソル
Dim rcLC As Long               'マウスカーソルの戻り値(形状) 格納用

Private Sub Form_Open(Cancel As Integer)
'マウスポインタを手の形にするためのマウスカーソル取得
    rcLC = LoadCursor(0&, IDC_HAND)
End Sub

Private Sub img_1_MouseMove(Button As Integer, _
    Shift As Integer, X As Single, Y As Single)
    'イメージの上ではマウスを手の形に変更する 2008/01/03 pPoy
    'ハンドカーソルをコール
    Call SetCursor(rcLC)
End Sub

• 画像をクリックする度に、新規画面で IE が開きます。
  続けて何回もクリックすると大変なことになりますので、注意してください。
  
  
• IE を開くときのサイズは、保存済みの画像に合わせて適当に変更してください。
  高さと幅を指定しない場合、規定のサイズで開きます。
  
  
• 画像ファイル名を間違って入力した場合は、エラーとなります。
  正しいファイル名を指定してください。
  
  
• 次のレコードに移動した時に、一瞬 「画像のインポート中」 のダイアログが表示されます。
  BMP ファイルが指定されたときは、あまり気にならずに表示できます。
  
  
• エラー処理で使用する 「くまさん.gif」 は、必ず他の画像と同じフォルダに保存してください。
  
  
• 画像をクリックして、拡張子に関連付けられたアプリケーションで開く方法は こちら です。