Private Sub Form_Current()
'指定された画像に入れ替える処理＆ハイパーリンク設定 2007/02/10 pPoy
On Error GoTo Err_Form_Current
    Dim myPath As String                '画像フォルダのパス
    Dim imgPath As String               '画像のフルパス
    
    myPath = CurrentProject.Path        '※ 自mdb のパス

    If IsNull(Me!FileName) Then
        '新規レコードに移動した際はデザイン時の画像を表示
        Me!img_1.Picture = myPath & "\くまさん.gif"
        Me!img_1.HyperlinkAddress = ""　　　　　　　'リンク無し
    Else
        imgPath = myPath & "\" & Me!FileName        'パス＆画像ファイル名
        With Me!img_1                               'イメージコントロール
            .Picture = imgPath                      '画像のフルパスセット
            .HyperlinkAddress = imgPath             'ハイパーリンク
            .ControlTipText = Nz(Me!myMemo)         'ヒントテキスト
        End With
    End If
    
Exit_Form_Current:
    Exit Sub
    
Err_Form_Current:
    MsgBox Err.Description
    Resume Exit_Form_Current
End Sub

Private Sub FileName_AfterUpdate()
'ファイル名を入力されたとき画像を表示後
'ハイパーリンク追加 2007/02/10 pPoy
On Error GoTo Err_FileName_AfterUpdate
    Dim myPath As String
    myPath = CurrentProject.Path     '※ 自mdb のパス(画像フォルダパス)
    Me!img_1.Picture = myPath & "\" & Me!FileName
    Me!img_1.HyperlinkAddress = myPath & "\" & Me!FileName

Exit_FileName_AfterUpdate:
    Exit Sub
    
Err_FileName_AfterUpdate:
    MsgBox Err.Description
    Resume Exit_FileName_AfterUpdate
End Sub

• 画像ファイル名を間違って入力した場合は、エラーとなります。
  正しいファイル名を指定してください。
  
  
• 次のレコードに移動した時に、一瞬 「画像のインポート中」 のダイアログが表示されます。
  BMP ファイルが指定されたときは、あまり気にならずに表示できます。
  
  
• この例では、画像のヒントテキスト (画像の上にマウスを置くと、暫くして表示される説明文) に、
  「myMemo」 フィールドの値を設定しています。
  何も設定しない場合、画像ファイルのフルパスが表示されます。
  
  
• クリックで起動するアプリケーションは、画像の拡張子に関連付けされているものです。
  エクスプローラで、画像ファイルをダブルクリックして開くアプリケーションと同一です。
  
  
• 画像をクリックして、IE で開く方法は こちら です。